test: Add test assets

CHANGELOG.md

@@ -9,6 +9,24 @@ Initial release of Clinical-Genomics/oncoflow, created with the [nf-core](https:
 
 ### `Added`
 
+- [#2](https://github.com/Clinical-Genomics/oncoflow/pull/2) Added `NEXTFLOW_RUN` local module based on `mahesh-panchal/nf-cascade`.
+- [#3](https://github.com/Clinical-Genomics/oncoflow/pull/3) Added `NFCORE_ONCOANALYSER` using the `NEXTFLOW_RUN` local module to run the `nf-core/oncoanalyser` pipeline in `ONCOFLOW` workflow.
+- [#3](https://github.com/Clinical-Genomics/oncoflow/pull/3) Added input parameters for running `nf-core/oncoanalyser`: `oncoanalyser_config`, `oncoanalyser_nextflow_opts`, `oncoanalyser_params_file` and `oncoanalyser_samplesheet`.
+- [#5](https://github.com/Clinical-Genomics/oncoflow/pull/5) Added `CREATE_ONCOREFINER_PARAMS_FILE` local module.
+- [#5](https://github.com/Clinical-Genomics/oncoflow/pull/5) Added metadata parameters `case_id`, `sample_id_tumor`, `sample_id_normal`, `subject_id` and `sex`, necessary for creating the `oncoanalyser` params file using the `CREATE_ONCOREFINER_PARAMS_FILE` local module.
+- [#5](https://github.com/Clinical-Genomics/oncoflow/pull/5) Added `CREATE_ONCOREFINER_PARAMS_FILE` module to `ONCOFLOW` workflow.
+- [#4](https://github.com/Clinical-Genomics/oncoflow/pull/4) Added `CLINICAL_GENOMICS_ONCOREFINER` using the `NEXTFLOW_RUN` local module to run the `Clinical-Genomics/oncorefiner` pipeline in `ONCOFLOW` workflow.
+- [#4](https://github.com/Clinical-Genomics/oncoflow/pull/4) Added input parameters for running `Clinical-Genomics/oncorefiner`: `oncorefiner_config` and `oncorefiner_nextflow_opts`.
+
+### `Changed`
+
+- [#3](https://github.com/Clinical-Genomics/oncoflow/pull/3) Changed default test to not capture `pipeline_info` files for all pipelines.
+- [#3](https://github.com/Clinical-Genomics/oncoflow/pull/3) and [#4](https://github.com/Clinical-Genomics/oncoflow/pull/4) Updated `.nftignore` to ignore `pipeline_info`, `multiqc` and `vep` files for all pipelines.
+- [#3](https://github.com/Clinical-Genomics/oncoflow/pull/3) Updated `.nftignore` to ignore gzipped output files from `oncoanalyser` due to https://github.com/nf-core/oncoanalyser/issues/299.
+- [#3](https://github.com/Clinical-Genomics/oncoflow/pull/3) Updated `.nftignore` to ignore `*.command.*` output files from `oncoanalyser` since several files include the run directory and platform information which changes for each run and therefore cannot be snapshot.
+- [#8](https://github.com/Clinical-Genomics/oncoflow/pull/8) Changed `NFCORE_ONCOANALYSER` to run forked fixed `Clinical-Genomics/oncoanalyser` instead, due to bug https://github.com/nf-core/oncoanalyser/issues/301.
+- [#8](https://github.com/Clinical-Genomics/oncoflow/pull/8) Changed test config to run the above with revision `2.2.0-with-purple-tbi-fix` which includes the fix for https://github.com/nf-core/oncoanalyser/issues/301 and `nf-core/oncoanalyser` version 2.2.0 since this was the version used for previous test runs.
+
 ### `Fixed`
 
 ### `Dependencies`

assets/test_oncoflow.config

@@ -0,0 +1,93 @@
+//
+// Oncoanalyser configuration
+//
+
+// TODO
+
+//
+// Oncorefiner configuration
+//
+
+// TODO
+params {
+    // Parameters and options for tools
+    extra_args_cadd_annotate = '--columns Chrom,Pos,Ref,Alt,-,CADD'
+    extra_args_snv_clinical_filter = "--include '(INFO/GNOMADAF_grpmax <= 0.001 || INFO/GNOMADAF_grpmax == \".\")'"
+    extra_args_snv_research_filter = "--include '(INFO/GNOMADAF_grpmax <= 0.001 || INFO/GNOMADAF_grpmax == \".\")'"
+    extra_args_snv_vep = ''
+    extra_args_sv_vep = ''
+
+    // Pipeline resource files
+    // VEP
+    vep_cache_version = 115
+    vep_plugin_files = params.oncoflow_resources_dir + 'vep_plugin.csv'
+    vep_cache = params.oncoflow_resources_dir + 'VEP'
+
+    // Vcfanno
+    vcfanno_toml = params.oncoflow_resources_dir + 'grch38_vcfanno_config.toml'
+    vcfanno_resources = params.oncoflow_resources_dir + 'grch38_vcfanno_resources.txt'
+    vcfanno_lua = null
+
+    // SVDB
+    svdb_query_dbs = params.oncoflow_resources_dir + 'grch38_svdb_query_dbs.csv'
+
+    // Reference
+    fasta = params.oncoflow_resources_dir + 'GRCh38_masked_exclusions_alts_hlas.fasta'
+    fai = params.oncoflow_resources_dir + 'GRCh38_masked_exclusions_alts_hlas.fasta.fai'
+}
+
+
+process {
+
+    withName: '.*:GENERATE_CYTOSURE_FILES:VCF2CYTOSURE' {
+        errorStrategy = 'ignore'
+    }
+
+    withName:'.*PROCESS_SNVS:BCFTOOLS_VIEW_RESEARCH' {
+       ext.args = { [
+       "${params.extra_args_snv_research_filter}",
+       "--output-type z",
+       "--write-index=tbi",
+       ].join(' ') }
+    }
+
+    withName: '.*PROCESS_SNVS:ENSEMBLVEP_VEP' {
+        maxForks = 8
+        memory = { 10.GB * task.attempt }
+        cpus = { 2 * task.attempt }
+        time = { 4.h * task.attempt }
+    }
+
+
+    withName: '.*PROCESS_SVS:ENSEMBLVEP_VEP' {
+        maxForks = 8
+        memory = { 10.GB * task.attempt }
+        cpus = { 2 * task.attempt }
+        time = { 4.h * task.attempt }
+    }
+
+    withName: '.*ANNOTATE_CADD:CADD' {
+        memory = { 30.GB * task.attempt }
+        cpus = { 1 * task.attempt }
+        time = { 1.h * task.attempt }
+    }
+
+    withName: '.*ANNOTATE_CADD:RENAME_CHR_CADD' {
+        memory = { 1.GB * task.attempt }
+        cpus = { 1 * task.attempt }
+        time = { 1.h * task.attempt }
+    }
+
+    withName: '.*ANNOTATE_CADD:ANNOTATE_INDELS' {
+        memory = { 1.GB * task.attempt }
+        cpus = { 1 * task.attempt }
+        time = { 1.h * task.attempt }
+    }
+
+    withName: '.*ANNOTATE_CADD:BCFTOOLS_VIEW' {
+        memory = { 1.GB * task.attempt }
+        cpus = { 1 * task.attempt }
+        time = { 1.h * task.attempt }
+    }
+
+}

assets/test_oncoflow_params.yaml

@@ -0,0 +1,8 @@
+case_id: "test_case_id"
+sample_id_tumor: "test_sample_id_tumor"
+sample_id_normal: "test_sample_id_normal"
+sex: "female"
+
+oncoanalyser_create_stub_placeholders: true
+oncoanalyser_genome: "GRCh38_hmf"
+oncoanalyser_mode: "wgts"

conf/test.config

@@ -19,11 +19,19 @@ process {
 }
 
 params {
-    config_profile_name        = 'Test profile'
-    config_profile_description = 'Minimal test dataset to check pipeline function'
+    config_profile_name        = 'Test profile (stub runs for all pipelines)'
+    config_profile_description = 'Minimal test where all pipelines are run in stub mode to check that pipelines are run sequentially'
 
-    // Input data
-    // TODO nf-core: Specify the paths to your test data on nf-core/test-datasets
-    // TODO nf-core: Give any required params for the test so that command line flags are not needed
-    input  = params.pipelines_testdata_base_path + 'viralrecon/samplesheet/samplesheet_test_illumina_amplicon.csv'
+    // Metadata
+    case_id          = 'test_case_id'
+    sample_id_tumor  = 'test_sample_id_tumor'
+    sample_id_normal = 'test_sample_id_normal'
+    subject_id       = 'subject_a' // matches the subject_id in the sample sheet of the test data of the oncoanalyser pipeline
+    sex              = 'female'
+
+    // Oncoanalyser input parameters
+    oncoanalyser_nextflow_opts = '-profile test_stub,docker -stub -revision 2.2.0-with-purple-tbi-fix'
+
+    // Oncorefiner input parameters
+    oncorefiner_nextflow_opts = '-profile test,docker -revision dev -stub'
 }

docs/parameters.md

@@ -2,6 +2,38 @@
 
 Pipeline cascade of nf-core/oncoanalyser + Clinical-Genomics/oncorefiner, written in Nextflow.
 
+## Metadata
+
+
+
+| Parameter | Description | Type | Default | Required | Hidden |
+|-----------|-----------|-----------|-----------|-----------|-----------|
+| `case_id` | Case ID. | `string` |  | True |  |
+| `sample_id_tumor` | Sample id of the tumor sample. | `string` |  | True |  |
+| `sample_id_normal` | Sample id of the normal sample. | `string` |  | True |  |
+| `subject_id` | Subject ID of the patient. | `string` |  | True |  |
+| `sex` | Sex of the patient. (accepted: `female`\|`male`\|`unknown`) | `string` |  | True |  |
+
+## Oncoanalyser
+
+Input files and nextflow options for running nf-core/oncoanlyser.
+
+| Parameter | Description | Type | Default | Required | Hidden |
+|-----------|-----------|-----------|-----------|-----------|-----------|
+| `oncoanalyser_config` | Path to config file for nf-core/oncoanlyser (optional). | `string` |  |  |  |
+| `oncoanalyser_nextflow_opts` | Nextflow options for running nf-core/oncoanlyser. | `string` |  | True |  |
+| `oncoanalyser_params_file` | Path to params file for nf-core/oncoanlyser. | `string` |  |  |  |
+| `oncoanalyser_samplesheet` | Path to csv samplesheet file for nf-core/oncoanalyser. | `string` |  |  |  |
+
+## Oncorefiner
+
+Input files and nextflow options for running Clinical-Genomics/oncorefiner.
+
+| Parameter | Description | Type | Default | Required | Hidden |
+|-----------|-----------|-----------|-----------|-----------|-----------|
+| `oncorefiner_config` | Path to config file for Clinical-Genomics/oncorefiner (optional). | `string` |  |  |  |
+| `oncorefiner_nextflow_opts` | Nextflow options for running Clinical-Genomics/oncorefiner. | `string` |  | True |  |
+
 ## Input/output options
 
 Define where the pipeline should find input data and save output data.

main.nf

@@ -12,8 +12,7 @@
     IMPORT FUNCTIONS / MODULES / SUBWORKFLOWS / WORKFLOWS
 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 */
-
-include { ONCOFLOW  } from './workflows/oncoflow'
+include { ONCOFLOW                } from './workflows/oncoflow'
 include { PIPELINE_INITIALISATION } from './subworkflows/local/utils_nfcore_oncoflow_pipeline'
 include { PIPELINE_COMPLETION     } from './subworkflows/local/utils_nfcore_oncoflow_pipeline'
 /*
@@ -28,16 +27,43 @@ include { PIPELINE_COMPLETION     } from './subworkflows/local/utils_nfcore_onco
 workflow CLINICALGENOMICS_ONCOFLOW {
 
     take:
-    outdir // string: The output directory where the results will be saved
+    val_case_id                    // string: [mandatory] Case ID
+    val_oncoanalyser_config        // string: [optional]  Config file for oncoanalyser pipeline
+    val_oncoanalyser_nextflow_opts // string: [mandatory] Nextflow options for oncoanalyser pipeline
+    val_oncoanalyser_params_file   // string: [mandatory] Parameters file for oncoanalyser pipeline
+    val_oncoanalyser_samplesheet   // string: [mandatory] Samplesheet file for oncoanalyser pipeline
+    val_oncorefiner_config         // string: [optional]  Config file for oncorefiner pipeline
+    val_oncorefiner_nextflow_opts  // string: [mandatory] Nextflow options for oncorefiner pipeline
+    val_outdir                     // string: [mandatory] The output directory where the results will be saved
+    val_sample_id_tumor            // string: [mandatory] Sample ID of the tumor sample
+    val_sample_id_normal           // string: [mandatory] Sample ID of the normal sample
+    val_subject_id                 // string: [mandatory] Subject ID
+    val_sex                        // string: [mandatory] Sex of the patient
 
     main:
 
     //
     // WORKFLOW: Run pipeline
     //
     ONCOFLOW (
-        outdir,
+        val_case_id,
+        val_oncoanalyser_config,
+        val_oncoanalyser_nextflow_opts,
+        val_oncoanalyser_params_file,
+        val_oncoanalyser_samplesheet,
+        val_oncorefiner_config,
+        val_oncorefiner_nextflow_opts,
+        val_sample_id_tumor,
+        val_sample_id_normal,
+        val_subject_id,
+        val_sex,
+        val_outdir
     )
+
+    emit:
+    oncoanalyser_output     = ONCOFLOW.out.oncoanalyser_output     // channel: [path(analysis_output_directory)]
+    oncorefiner_output      = ONCOFLOW.out.oncorefiner_output      // channel: [path(analysis_output_directory)]
+    oncorefiner_params_file = ONCOFLOW.out.oncorefiner_params_file // channel: [path(yaml)]
 }
 /*
 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
@@ -66,6 +92,17 @@ workflow {
     // WORKFLOW: Run main workflow
     //
     CLINICALGENOMICS_ONCOFLOW (
+        params.case_id,
+        params.oncoanalyser_config,
+        params.oncoanalyser_nextflow_opts,
+        params.oncoanalyser_params_file,
+        params.oncoanalyser_samplesheet,
+        params.oncorefiner_config,
+        params.oncorefiner_nextflow_opts,
+        params.sample_id_tumor,
+        params.sample_id_normal,
+        params.subject_id,
+        params.sex,
         params.outdir
     )
 
@@ -79,6 +116,23 @@ workflow {
         params.outdir,
         params.monochrome_logs,
     )
+
+    publish:
+    oncoanalyser_output     = CLINICALGENOMICS_ONCOFLOW.out.oncoanalyser_output
+    oncorefiner_output      = CLINICALGENOMICS_ONCOFLOW.out.oncorefiner_output
+    oncorefiner_params_file = CLINICALGENOMICS_ONCOFLOW.out.oncorefiner_params_file
+}
+
+output {
+    oncoanalyser_output {
+        path "oncoanalyser"
+    }
+    oncorefiner_output {
+        path "oncorefiner"
+    }
+    oncorefiner_params_file {
+        path "oncorefiner"
+    }
 }
 
 /*

modules/local/createoncorefinerparamsfile/main.nf

@@ -0,0 +1,55 @@
+process CREATE_ONCOREFINER_PARAMS_FILE {
+    tag 'oncorefiner'
+    label 'process_single'
+
+    input:
+    val case_id
+    val subject_id
+    val sample_id_tumor
+    val sample_id_normal
+    val sex
+    path oncoanalyser_results_dir
+    val outdir
+
+    output:
+
+    path "oncorefiner_params.yaml", emit: params_file
+    // WARN: Please update version string when the module is updated.
+    tuple val("${task.process}"), val('createoncorefinerparamsfile'), val('1.0'), topic: versions, emit: versions_createoncorefinerparamsfile
+
+    when:
+    task.ext.when == null || task.ext.when
+
+    script:
+    def oncoanalyser_output_dir = file(outdir).resolve("oncoanalyser/${oncoanalyser_results_dir}")
+
+    def snv_vcf_path    = oncoanalyser_output_dir.resolve("${subject_id}/purple/${subject_id}.tumor.purple.somatic.vcf.gz")
+    def sv_vcf_path     = oncoanalyser_output_dir.resolve("${subject_id}/purple/${subject_id}.tumor.purple.sv.vcf.gz")
+    def bam_tumor_path  = oncoanalyser_output_dir.resolve("${subject_id}/alignments/dna/${subject_id}.tumor.redux.bam")
+    def bai_tumor_path  = oncoanalyser_output_dir.resolve("${subject_id}/alignments/dna/${subject_id}.tumor.redux.bam.bai")
+    def bam_normal_path = sample_id_normal ? oncoanalyser_output_dir.resolve("${subject_id}/alignments/dna/${subject_id}.normal.redux.bam") : ''
+    def bai_normal_path = sample_id_normal ? oncoanalyser_output_dir.resolve("${subject_id}/alignments/dna/${subject_id}.normal.redux.bam.bai") : ''
+
+    def oncorefiner_params_file =
+        [
+            "case_id: ${case_id}",
+            "sample_id_tumor: ${sample_id_tumor}",
+            "sample_id_normal: ${sample_id_normal}",
+            "sex: ${sex}",
+            "snv_vcf: ${snv_vcf_path}",
+            "sv_vcf: ${sv_vcf_path}",
+            "bam_tumor: ${bam_tumor_path}",
+            "bai_tumor: ${bai_tumor_path}",
+            "bam_normal: ${bam_normal_path}",
+            "bai_normal: ${bai_normal_path}"
+        ].join("\\n")
+
+    """
+    printf "$oncorefiner_params_file" > oncorefiner_params.yaml
+    """
+
+    stub:
+    """
+    touch oncorefiner_params.yaml
+    """
+}