emcutils/build.gradle at 1.21 · triphora/emcutils · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
plugins {
	alias libs.plugins.architectury.plugin
	alias libs.plugins.architectury.loom apply false
}

String mcVer = libs.versions.minecraft.get()
architectury.minecraft = mcVer

subprojects {
	apply plugin: 'dev.architectury.loom'

	repositories {
		[
			['Modrinth', 'api.modrinth.com/maven', ['maven.modrinth'], []],
			['NeoForge', 'maven.neoforged.net/releases', [], []],
		].forEach { var mavenInfo ->
			exclusiveContent {
				forRepository {
					maven {
						name = mavenInfo[0]
						url = 'https://' + mavenInfo[1]
					}
				}
				filter {
					mavenInfo[2].forEach { String group ->
						includeGroup group
					}
					mavenInfo[3].forEach { String group ->
						includeGroupByRegex group
					}
				}
			}
		}
	}

	dependencies {
		minecraft libs.minecraft
		mappings loom.officialMojangMappings()
	}

	loom {
		runtimeOnlyLog4j = true

		runs {
			configureEach {
				vmArg '-Dmixin.debug.export=true'
			}
		}
	}
}

allprojects {
	apply plugin: 'java'
	apply plugin: 'architectury-plugin'
	apply plugin: 'maven-publish'

	group = 'coffee.waffle'
	base.archivesName = "emcutils-$project.name-$mcVer"
	version = rootProject.mod_version

	tasks.withType(JavaCompile).configureEach {
		options.encoding = 'UTF-8'
		options.release.set 21
	}

	java.withSourcesJar()

	jar.from 'LICENSE'
}