КомандаInstall.os

#Использовать "../../core"

&ЛогOVM
Перем Лог;

&Пластилин
Перем УстановщикOneScript;

&Пластилин("ДетекторОкружения")
Перем Окружение;

&Аргумент(
	Имя = "VERSION",
	Описание = "Устанавливаемая версия (версии) OneScript. "
		"Допустимо использовать трехномерные версии (1.0.17, 1.0.18), "
		"lts, stable, dev, preview, lts-dev. "
		"Может быть передано несколько значений"
)
&ТМассивСтрок
&ВОкружении("OVM_INSTALL_VERSION")
Перем МассивВерсийКУстановке;

&Опция(Имя = "name", Описание = "Синоним (алиас) устанавливаемой версии для последующего использования в ovm use")
&ТСтрока
&ВОкружении("OVM_INSTALL_NAME")
Перем АлиасВерсии;

&Опция(Имя = "clean c", Описание = "Полностью очищать каталог установки (включая установленные библиотеки)")
&ПоУмолчанию(Ложь)
&ТБулево
&ВОкружении("OVM_INSTALL_CLEAN")
Перем ОчищатьКаталогУстановки;

&Опция(Имя = "x86", Описание = "Устанавливать 32-разрядный дистрибутив OneScript")
&ПоУмолчанию(Ложь)
&ТБулево
&ВОкружении("OVM_INSTALL_X86")
Перем Устанавливать32РазряднуюВерсию;

&Опция(Имя = "fdd", Описание = "Устанавливать fdd дистрибутив OneScript (требует установленный .NET для работы)")
&ПоУмолчанию(Ложь)
&ТБулево
&ВОкружении("OVM_INSTALL_FDD")
Перем УстанавливатьFDDДистрибутив;

&КомандаПриложения(Имя = "install i", Описание = "Установить OneScript указанных версий")
Процедура ПриСозданииОбъекта()
КонецПроцедуры

&ВыполнениеКоманды
Процедура ВыполнениеКоманды() Экспорт

	Если ЗначениеЗаполнено(АлиасВерсии) И МассивВерсийКУстановке.Количество() > 1 Тогда
		ВызватьИсключение "Опция <--name> может быть задана только при установке одной версии OneScript";
	КонецЕсли;

	ДополнительныеПараметры = УстановщикOneScript.ДополнительныеПараметрыУстановки();
	ДополнительныеПараметры.ОчищатьКаталогУстановки = ОчищатьКаталогУстановки;

	Если Окружение.ЭтоX64() Тогда
		ДополнительныеПараметры.ИспользоватьХ64 = НЕ Устанавливать32РазряднуюВерсию;
	Иначе
		ДополнительныеПараметры.ИспользоватьХ64 = Ложь;
	КонецЕсли;

	ДополнительныеПараметры.ИспользоватьFDD = УстанавливатьFDDДистрибутив;

	Для Каждого ВерсияКУстановке Из МассивВерсийКУстановке Цикл
		УстановщикOneScript.УстановитьOneScript(ВерсияКУстановке, АлиасВерсии, ДополнительныеПараметры);
	КонецЦикла;

	Если МассивВерсийКУстановке.Количество() > 0 Тогда
		Лог.Информация(
			"Для начала использования версии OneScript, выполните команду:
			|ovm use %1",
			?(ЗначениеЗаполнено(АлиасВерсии), АлиасВерсии, МассивВерсийКУстановке[МассивВерсийКУстановке.ВГраница()])
		);
	КонецЕсли;

КонецПроцедуры