RTClock implementation for STM32F103

[abhaysbharadwaj]

Hello,
I had worked with the old core (Roger Clark) and I had used the <RTClock.h> library to get the systick time to understand the "System uptime" (basically number of seconds the microcontroller is running without a power cycle). This was helping me in determining a system's long time performance on whether it used to work continuously or if it was getting stuck and a power cycle was done to reset the microcontroller.

The same RTClock is not working for this core. Is a similar library available here? Or is there a way I can get the systick seconds in my code? Any help is appreciated.

[fpistm]

You can simply use millis()
https://www.arduino.cc/reference/en/language/functions/time/millis/

Or you can use the STM32RTC:
https://github.com/stm32duino/STM32RTC

[abhaysbharadwaj]

Hi,

millis() does not work since it gets reset to zero every time the microcontroller is reset using the "RESET" pin or "NVIC_System_Reset"

With RTClock, the count would get reset to 0 only with a power cycle (switch off - switch on) of the controller. Even putting the system to sleep and wake-up or using the NVIC_systemReset was not resetting the count.

RTC is being used for STANDBY mode (deep sleep functionality). I am not sure how I can use it for getting the "Device up-time".

[fpistm]

I don't see this kind of feature in the RTCLock.h.
Maybe You can use dwt for this:
https://github.com/stm32duino/Arduino_Core_STM32/blob/main/cores/arduino/stm32/dwt.h

[abhaysbharadwaj]

I think my explanation was not clear.
Adding an example to illustrate what I mean:

Test Code:

#include <RTClock.h>
RTClock rt(RTCSEL_LSE); //internal RTC class
int counter = 0;

//store the device up-time count
unsigned long deviceOperationTime = 0;
void setup()
{
  Serial.begin(115200);
  Serial.println("Device Powered ON");
}

void loop()
{
  ++counter;
  Serial.print("Count: "); Serial.print(counter); Serial.print("\t");

  deviceOperationTime = rt.getTime();
  Serial.print("Device Up-time: "); Serial.print(deviceOperationTime); Serial.println(" Seconds");

  if (counter >= 5)
  {
    Serial.println("Max count reached. Triggering NVIC_SYS_RESET.");
    delay(100);
    nvic_sys_reset();
  }
  delay(5000);
}

Image:

[fpistm]

you want something like a free running counter.
You can try something like this as a workaround

#include <STM32RTC.h>
#include "stm32yyxx_ll_rcc.h"

static int counter = 0;

//store the device up-time count
static unsigned long deviceOperationTime = 0;
static unsigned long offsetOPTime = 0;
STM32RTC& rtc = STM32RTC::getInstance();

void setup()
{
  Serial.begin(115200);
  Serial.println("Device Powered ON");
  rtc.begin();
  rtc.attachSecondsInterrupt(rtc_SecondsCB);
  dwt_init();
  enableBackupDomain();
  if(LL_RCC_IsActiveFlag_SFTRST() || LL_RCC_IsActiveFlag_PINRST()) {
    offsetOPTime += getBackupRegister(LL_RTC_BKP_DR2);
    LL_RCC_ClearResetFlags();
  } else {
    resetBackupDomain();
  }
}

void loop()
{
  ++counter;
  Serial.printf("Count: %i\t", counter);
  deviceOperationTime = (dwt_getCycles()/SystemCoreClock) + offsetOPTime;
  Serial.printf("Device Up-time: %i Seconds\n", deviceOperationTime);

  if (counter >= 5)
  {
    Serial.println("Max count reached. Triggering NVIC_SystemReset.");
    delay(100);
    setBackupRegister(LL_RTC_BKP_DR2, deviceOperationTime);
    NVIC_SystemReset();
  }
  delay(5000);
}

/* callback function on each second interrupt */
void rtc_SecondsCB(void *data)
{
  UNUSED(data);
  setBackupRegister(LL_RTC_BKP_DR2, (dwt_getCycles()/SystemCoreClock) + offsetOPTime);

}

[abhaysbharadwaj]

Will check this out! Thank you.

[fpistm]

Note that it is really a workaround.
It is planned to provide a new RTC feature to have a free running counter, anyway, maybe it will continue to run when reset occurs.