lpfp/rotation.asm at master · nagydani/lpfp · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
; Unit quaternion multiplication and normalization, if necessary
; Input: {RIJK}{12} the two multiplicands
; Output: {RIJK}1 the product quaternion
; Pollutes: AF,AF',BC,DE,HL
QMUL:	LD	BC,(R1)
	LD	DE,(R2)
	CALL	FMUL
	PUSH	HL
	LD	BC,(I1)
	LD	DE,(I2)
	CALL	FMUL
	PUSH	HL
	LD	BC,(J1)
	LD	DE,(J2)
	CALL	FMUL
	POP	DE
	CALL	FADD
	PUSH	HL
	LD	BC,(K1)
	LD	DE,(K2)
	CALL	FMUL
	POP	DE
	CALL	FADD
	POP	DE
	EX	DE,HL
	CALL	FSUB
	PUSH	HL	; real
	LD	BC,(K1)
	LD	DE,(J2)
	CALL	FMUL
	PUSH	HL
	LD	BC,(R1)
	LD	DE,(I2)
	CALL	FMUL
	PUSH	HL
	LD	BC,(R2)
	LD	DE,(I1)
	CALL	FMUL
	POP	DE
	CALL	FADD
	PUSH	HL
	LD	BC,(J1)
	LD	DE,(K2)
	CALL	FMUL
	POP	DE
	CALL	FADD
	POP	DE
	CALL	FSUB
	PUSH	HL	; i
	LD	BC,(I1)
	LD	DE,(K2)
	CALL	FMUL
	PUSH	HL
	LD	BC,(R1)
	LD	DE,(J2)
	CALL	FMUL
	PUSH	HL
	LD	BC,(J1)
	LD	DE,(R2)
	CALL	FMUL
	POP	DE
	CALL	FADD
	PUSH	HL
	LD	BC,(K1)
	LD	DE,(I2)
	CALL	FMUL
	POP	DE
	CALL	FADD
	POP	DE
	CALL	FSUB
	PUSH	HL	; j
	LD	BC,(J1)
	LD	DE,(I2)
	CALL	FMUL
	PUSH	HL
	LD	BC,(R1)
	LD	DE,(K2)
	CALL	FMUL
	PUSH	HL
	LD	BC,(I1)
	LD	DE,(J2)
	CALL	FMUL
	POP	DE
	CALL	FADD
	PUSH	HL
	LD	BC,(K1)
	LD	DE,(R2)
	CALL	FMUL
	POP	DE
	CALL	FADD
	POP	DE
	CALL	FSUB
	LD	(K1),HL	; k
	; Normalize
	CALL	FSQUARE
	EX	(SP),HL
	LD	(J1),HL
	CALL	FSQUARE
	POP	DE
	CALL	FADD
	EX	(SP),HL
	LD	(I1),HL
	CALL	FSQUARE
	POP	DE
	CALL	FADD
	EX	(SP),HL
	LD	(R1),HL
	CALL	FSQUARE
	POP	DE
	CALL	FADD
	LD	DE,ONEF
	CALL	FSUB
	LD	A,H
	ADD	A,A
	CP	$70
	RET	C	; deviation from 1 smaller than 2^-8
	EX	DE,HL
	INC	D
	LD	HL,ONEF
	CALL	FSUB
	PUSH	HL	; 1/norm
	LD	C,L
	LD	B,H
	LD	DE,(R1)
	CALL	FMUL
	LD	(R1),HL
	POP	BC
	PUSH	BC
	LD	DE,(I1)
	CALL	FMUL
	LD	(I1),HL
	POP	BC
	PUSH	BC
	LD	DE,(J1)
	CALL	FMUL
	LD	(J1),HL
	POP	BC
	LD	DE,(K1)
	CALL	FMUL
	LD	(K1),HL
	RET

; Inverse quaternion
; Input: {RIJK}1 = quaternion to invert
; Output: {RIJK}1 = inverse
; Pollutes: A,C
QINV:	LD	C,$80
	LD	A,(I1+1)
	XOR	C
	LD	(I1+1),A
	LD	A,(J1+1)
	XOR	C
	LD	(J1+1),A
	LD	A,(K1+1)
	XOR	C
	LD	(K1+1),A
	RET

; Convert unit quaternion to rotation matrix
QMAT:	LD	HL,(I1)
	CALL	FSQUARE
	PUSH	HL
	EX	DE,HL
	LD	HL,(J1)
	CALL	FSQUARE
	PUSH	HL
	CALL	FADDP
	INC	H
	SET	7,H
	LD	DE,ONEF
	CALL	FADD
	LD	(Z3),HL
	POP	DE
	LD	HL,(K1)
	CALL	FSQUARE
	PUSH	HL
	CALL	FADDP
	INC	H
	SET	7,H
	LD	DE,ONEF
	CALL	FADD
	LD	(X1),HL
	POP	HL
	POP	DE
	CALL	FADDP
	INC	H
	SET	7,H
	LD	DE,ONEF
	CALL	FADD
	LD	(Y2),HL
	LD	BC,(K1)
	LD	DE,(R1)
	CALL	FMUL
	PUSH	HL
	PUSH	HL
	LD	BC,(I1)
	LD	DE,(J1)
	CALL	FMUL
	POP	DE
	PUSH	HL
	CALL	FSUB
	INC	H
	LD	(X2),HL
	POP	HL
	POP	DE
	CALL	FADD
	INC	H
	LD	(Y1),HL
	LD	BC,(J1)
	LD	DE,(R1)
	CALL	FMUL
	PUSH	HL
	PUSH	HL
	LD	BC,(I1)
	LD	DE,(K1)
	CALL	FMUL
	POP	DE
	PUSH	HL
	CALL	FSUB
	INC	H
	LD	(Z1),HL
	POP	HL
	POP	DE
	CALL	FADD
	INC	H
	LD	(X3),HL
	LD	BC,(I1)
	LD	DE,(R1)
	CALL	FMUL
	PUSH	HL
	PUSH	HL
	LD	BC,(K1)
	LD	DE,(J1)
	CALL	FMUL
	POP	DE
	PUSH	HL
	CALL	FSUB
	INC	H
	LD	(Y3),HL
	POP	HL
	POP	DE
	CALL	FADD
	INC	H
	LD	(Z2),HL
	RET


; First quaternion
R1:	DEFS	2
I1:	DEFS	2
J1:	DEFS	2
K1:	DEFS	2
; Second quaternion
R2:	DEFS	2
I2:	DEFS	2
J2:	DEFS	2
K2:	DEFS	2
; Rotation Matrix
X1:	DEFS	2
Y1:	DEFS	2
Z1:	DEFS	2
X2:	DEFS	2
Y2:	DEFS	2
Z2:	DEFS	2
X3:	DEFS	2
Y3:	DEFS	2
Z3:	DEFS	2