build.gradle

plugins {
  id 'org.jetbrains.kotlin.jvm' version '2.3.21' apply false
  id 'org.jetbrains.kotlin.plugin.spring' version '2.3.21' apply false
  id 'org.springframework.boot' version '4.0.6' apply false
  id 'org.jlleitschuh.gradle.ktlint' version '14.0.1' apply false
}

subprojects {
  group = 'io.meshcloud.buildingblocks'

  repositories {
    mavenCentral()
  }

  pluginManager.withPlugin('org.jetbrains.kotlin.jvm') {
    apply plugin: 'org.jlleitschuh.gradle.ktlint'

    ktlint {
      // Keep in sync with meshfed-release. The jlleitschuh plugin manages its own detached
      // configuration for the ktlint CLI, so this DSL is the only supported way to set the version.
      version = "1.8.0"
    }

    kotlin {
      compilerOptions {
        freeCompilerArgs.addAll '-Xjsr305=strict', '-Xannotation-default-target=param-property'
      }
    }
  }

  pluginManager.withPlugin('java') {
    java {
      toolchain {
        languageVersion.set(JavaLanguageVersion.of(21))
      }
    }

    dependencies {
      implementation(platform('org.springframework.boot:spring-boot-dependencies:3.5.13'))
      implementation(enforcedPlatform('org.jetbrains.kotlin:kotlin-bom:2.1.21'))

      testRuntimeOnly 'org.junit.platform:junit-platform-launcher'

      constraints {
        implementation('io.github.oshai:kotlin-logging:8.0.03')
        implementation('com.squareup.okhttp3:okhttp:5.3.2')
        implementation('com.squareup.okhttp3:logging-interceptor:5.3.2')
        implementation('com.squareup.okhttp3:mockwebserver:5.3.2')
        implementation('org.hashids:hashids:1.0.3')
        implementation('org.bouncycastle:bcprov-jdk18on:1.84')
        implementation('com.auth0:java-jwt:4.5.2')

        testImplementation('io.mockk:mockk:1.14.9')
        testImplementation('org.wiremock:wiremock-jetty12:3.13.2')
      }
    }

    tasks.withType(Test).configureEach {
      useJUnitPlatform()
    }
  }
}