CMakeLists.txt

set(THREADS_PREFER_PTHREAD_FLAG ON)
find_package(Threads REQUIRED)

find_package(MAVLink REQUIRED)

get_target_property(
    MAVLINK_INCLUDE_DIR
    MAVLink::mavlink
    INTERFACE_INCLUDE_DIRECTORIES
)

configure_file(version.hpp.in version.hpp)
configure_file(include/mavsdk/mavlink_include.hpp.in include/mavsdk/mavlink_include.hpp)

# Generate embedded XML header for libmav
if(NOT MAVLINK_XML_PATH)
    # Derive from MAVLINK_INCLUDE_DIR which is set by find_package(MAVLink)
    # MAVLINK_INCLUDE_DIR points to .../include, so we append mavlink/message_definitions/v1.0
    set(MAVLINK_XML_PATH "${MAVLINK_INCLUDE_DIR}/mavlink/message_definitions/v1.0")
endif()

set(MAVLINK_MINIMAL_XML "${MAVLINK_XML_PATH}/minimal.xml")
set(MAVLINK_STANDARD_XML "${MAVLINK_XML_PATH}/standard.xml")
set(MAVLINK_COMMON_XML "${MAVLINK_XML_PATH}/common.xml")
set(MAVLINK_ARDUPILOTMEGA_XML "${MAVLINK_XML_PATH}/ardupilotmega.xml")

set(EMBEDDED_XML_HEADER "${CMAKE_CURRENT_BINARY_DIR}/embedded_mavlink_xml.hpp")

add_custom_command(
    OUTPUT ${EMBEDDED_XML_HEADER}
    COMMAND ${CMAKE_COMMAND} 
        -DMINIMAL_XML_PATH=${MAVLINK_MINIMAL_XML}
        -DSTANDARD_XML_PATH=${MAVLINK_STANDARD_XML}
        -DCOMMON_XML_PATH=${MAVLINK_COMMON_XML}
        -DARDUPILOTMEGA_XML_PATH=${MAVLINK_ARDUPILOTMEGA_XML}
        -DOUTPUT_HEADER=${EMBEDDED_XML_HEADER}
        -P ${CMAKE_CURRENT_SOURCE_DIR}/../../../cmake/generate_embedded_xml.cmake
    DEPENDS ${MAVLINK_MINIMAL_XML} ${MAVLINK_STANDARD_XML} ${MAVLINK_COMMON_XML} ${MAVLINK_ARDUPILOTMEGA_XML}
    COMMENT "Generating embedded MAVLink XML header for core"
    VERBATIM
)

add_custom_target(generate_core_mavlink_xml_header DEPENDS ${EMBEDDED_XML_HEADER})

target_sources(mavsdk
    PRIVATE
    autopilot.cpp
    base64.cpp
    compatibility_mode.cpp
    call_every_handler.cpp
    callback_tracker.cpp
    connection.cpp
    connection_result.cpp
    crc32.cpp
    system.cpp
    system_impl.cpp
    file_cache.cpp
    flight_mode.cpp
    fs_utils.cpp
    hostname_to_ip.cpp
    inflate_lzma.cpp
    math_utils.cpp
    mavsdk.cpp
    asio_throw_exception.cpp
    mavsdk_impl.cpp
    mavlink_channel_status.cpp
    mavlink_channels.cpp
    mavlink_command_receiver.cpp
    mavlink_command_sender.cpp
    mavlink_component_metadata.cpp
    mavlink_ftp_client.cpp
    mavlink_ftp_server.cpp
    mavlink_mission_transfer_client.cpp
    mavlink_mission_transfer_server.cpp
    mavlink_parameter_cache.cpp
    mavlink_parameter_client.cpp
    mavlink_parameter_server.cpp
    mavlink_parameter_subscription.cpp
    mavlink_parameter_helper.cpp
    mavlink_receiver.cpp
    libmav_receiver.cpp
    libmav_conversions.cpp
    mavlink_request_message.cpp
    mavlink_request_message_handler.cpp
    mavlink_statustext_handler.cpp
    mavlink_message_handler.cpp
    param_value.cpp
    ping.cpp
    plugin_impl_base.cpp
    raw_connection.cpp
    serial_connection.cpp
    server_component.cpp
    server_component_impl.cpp
    server_plugin_impl_base.cpp
    tcp_client_connection.cpp
    tcp_server_connection.cpp
    timeout_handler.cpp
    udp_connection.cpp
    vehicle.cpp
    log.cpp
    cli_arg.cpp
    geometry.cpp
    mavsdk_time.cpp
    string_utils.cpp
    timesync.cpp
)

cmake_policy(SET CMP0079 NEW)
target_link_libraries(mavsdk
    PRIVATE
    Threads::Threads
    LibLZMA::LibLZMA
)

if (NOT BUILD_WITHOUT_CURL)
    target_sources(mavsdk
        PRIVATE
        curl_wrapper.cpp
        http_loader.cpp
    )

    target_link_libraries(mavsdk
        PRIVATE
        CURL::libcurl
    )

    list(APPEND UNIT_TEST_SOURCES
        ${PROJECT_SOURCE_DIR}/mavsdk/core/curl_test.cpp
        ${PROJECT_SOURCE_DIR}/mavsdk/core/hostname_to_ip_test.cpp
        ${PROJECT_SOURCE_DIR}/mavsdk/core/http_loader_test.cpp
    )
else()
    target_compile_definitions(mavsdk
        PRIVATE
        BUILD_WITHOUT_CURL=1
    )
endif()

target_compile_definitions(mavsdk PRIVATE MAVSDK_BUILD)

if (BUILD_SHARED_LIBS)
    target_compile_definitions(mavsdk PUBLIC MAVSDK_SHARED)
endif()

set_target_properties(mavsdk PROPERTIES
    VERSION ${MAVSDK_VERSION_STRING}
    SOVERSION ${MAVSDK_SOVERSION_STRING}
)
if (MSVC)
    set_target_properties(mavsdk PROPERTIES
        DEBUG_POSTFIX "d"
    )
endif()

if (IOS)
    target_link_libraries(mavsdk
        PUBLIC
        "-framework Foundation"
        "-framework Security"
    )
endif()

# Link to Windows networking lib.
if (MSVC OR MINGW)
    target_link_libraries(mavsdk
        PRIVATE
        ws2_32
    )
endif()

if(ANDROID)
    target_link_libraries(mavsdk
        PRIVATE
        log
    )
endif()

if((BUILD_STATIC_MAVSDK_SERVER AND ("${CMAKE_C_COMPILER_ID}" STREQUAL "GNU")) OR
    (${CMAKE_HOST_SYSTEM_PROCESSOR} MATCHES "(armv6|armv7|aarch64)"))
    target_link_libraries(mavsdk PRIVATE atomic)
endif()

set_target_properties(mavsdk
    PROPERTIES
        COMPILE_FLAGS ${warnings}
        CXX_VISIBILITY_PRESET hidden
        VISIBILITY_INLINES_HIDDEN ON
    )

# Use a linker symbol export list to hide symbols from statically-linked
# third-party libraries (OpenSSL, tinyxml2, curl, etc.).
# -fvisibility=hidden only affects code compiled with that flag;
# pre-built static archives still export their symbols without this.
if(BUILD_SHARED_LIBS)
    if(APPLE)
        target_link_options(mavsdk PRIVATE
            "LINKER:-exported_symbols_list,${CMAKE_CURRENT_SOURCE_DIR}/libmavsdk.exported_symbols"
        )
    elseif(UNIX)
        target_link_options(mavsdk PRIVATE
            "LINKER:--version-script=${CMAKE_CURRENT_SOURCE_DIR}/libmavsdk.version"
        )
    endif()
endif()

# Asio's io_context.hpp triggers a false-positive -Wnull-dereference with GCC
# (executor comparison at io_context.hpp:967).  The warning comes from GCC's
# data-flow analysis traversing inlined Asio internals; marking the Asio
# include directory as SYSTEM is not always sufficient to suppress it.
if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
    target_compile_options(mavsdk PRIVATE -Wno-null-dereference)
endif()

target_include_directories(mavsdk
    PUBLIC
    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include/mavsdk>
    $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}/include/mavsdk>
    $<BUILD_INTERFACE:${MAVLINK_INCLUDE_DIR}>
    $<INSTALL_INTERFACE:include>
    PRIVATE
    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
    $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>
    )

# Ensure the embedded XML header is generated before building
add_dependencies(mavsdk generate_core_mavlink_xml_header)

# Make sure libmav_receiver.cpp knows about the generated header
set_source_files_properties(libmav_receiver.cpp PROPERTIES OBJECT_DEPENDS ${EMBEDDED_XML_HEADER})

install(TARGETS mavsdk
    EXPORT mavsdk-targets
    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
    LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
    ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
    )

install(FILES
    include/mavsdk/autopilot.hpp
    include/mavsdk/base64.hpp
    include/mavsdk/compatibility_mode.hpp
    include/mavsdk/component_type.hpp
    include/mavsdk/connection_result.hpp
    include/mavsdk/deprecated.hpp
    include/mavsdk/handle.hpp
    include/mavsdk/system.hpp
    include/mavsdk/mavsdk.hpp
    include/mavsdk/mavsdk_export.h
    include/mavsdk/log_callback.hpp
    include/mavsdk/plugin_base.hpp
    include/mavsdk/server_plugin_base.hpp
    include/mavsdk/geometry.hpp
    include/mavsdk/math_utils.hpp
    include/mavsdk/server_component.hpp
    include/mavsdk/mavlink_address.hpp
    include/mavsdk/vehicle.hpp
    include/mavsdk/overloaded.hpp
    ${CMAKE_CURRENT_BINARY_DIR}/include/mavsdk/mavlink_include.hpp
    DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/mavsdk"
)

install(DIRECTORY ${MAVLINK_INCLUDE_DIR}/mavlink
    DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/mavsdk"
)

list(APPEND UNIT_TEST_SOURCES
    ${PROJECT_SOURCE_DIR}/mavsdk/core/callback_list_test.cpp
    ${PROJECT_SOURCE_DIR}/mavsdk/core/call_every_handler_test.cpp
    ${PROJECT_SOURCE_DIR}/mavsdk/core/cli_arg_test.cpp
    ${PROJECT_SOURCE_DIR}/mavsdk/core/file_cache_test.cpp
    ${PROJECT_SOURCE_DIR}/mavsdk/core/locked_queue_test.cpp
    ${PROJECT_SOURCE_DIR}/mavsdk/core/geometry_test.cpp
    ${PROJECT_SOURCE_DIR}/mavsdk/core/heartbeat_watchdog_test.cpp
    ${PROJECT_SOURCE_DIR}/mavsdk/core/math_utils_test.cpp
    ${PROJECT_SOURCE_DIR}/mavsdk/core/mavsdk_test.cpp
    ${PROJECT_SOURCE_DIR}/mavsdk/core/mavsdk_time_test.cpp
    ${PROJECT_SOURCE_DIR}/mavsdk/core/mavlink_channels_test.cpp
    ${PROJECT_SOURCE_DIR}/mavsdk/core/mavlink_mission_transfer_client_test.cpp
    ${PROJECT_SOURCE_DIR}/mavsdk/core/mavlink_mission_transfer_server_test.cpp
    ${PROJECT_SOURCE_DIR}/mavsdk/core/mavlink_statustext_handler_test.cpp
    ${PROJECT_SOURCE_DIR}/mavsdk/core/ringbuffer_test.cpp
    ${PROJECT_SOURCE_DIR}/mavsdk/core/timeout_handler_test.cpp
    ${PROJECT_SOURCE_DIR}/mavsdk/core/unittests_main.cpp
    ${PROJECT_SOURCE_DIR}/mavsdk/core/mavlink_parameter_cache_test.cpp
    ${PROJECT_SOURCE_DIR}/mavsdk/core/string_utils_test.cpp
    ${PROJECT_SOURCE_DIR}/mavsdk/core/base64_test.cpp
)

if (NOT BUILD_WITHOUT_CURL)
    list(APPEND UNIT_TEST_SOURCES
        ${PROJECT_SOURCE_DIR}/mavsdk/core/mavlink_component_metadata_test.cpp
    )
endif()
set(UNIT_TEST_SOURCES ${UNIT_TEST_SOURCES} PARENT_SCOPE)