add missing files

Author: Krusty/Benediction

cpclib-asm/assets/uncrunch/bzpack_backward_bx0.asm

@@ -0,0 +1,55 @@
+; Copyright (c) 2025, Milos "baze" Bazelides
+; This code is licensed under the BSD 2-Clause License.
+
+; Reverse BX0 decoder (68 bytes with setup, 62 bytes excluding setup).
+; This work is inspired by Einar Saukas' ZX0 (https://github.com/einar-saukas/ZX0).
+
+		xor	a
+		push	af		; Push dummy value onto the stack.
+		ld	hl,SrcAddr
+		ld	de,DstAddr
+
+DecodeLoop	call	EliasGamma
+		lddr
+		rla
+		jr	c,NewOffset
+
+		call	EliasGamma
+
+RepOffset	ex	(sp),hl
+		push	hl
+		add	hl,de
+		lddr
+		pop	hl
+		ex	(sp),hl
+		rla
+		jr	nc,DecodeLoop
+
+NewOffset	pop	bc
+		or	a
+		call	EliasGamma
+		dec	c
+		ret	m		; Option to include the end-of-stream marker.
+		ld	b,c
+		ld	c,(hl)
+		dec	hl
+		rr	b
+		rr	c
+		rra
+;		inc	bc		; Option to extend the offset range.
+		push	bc
+		call	EliasGamma
+		inc	bc
+		jr	RepOffset
+
+EliasGamma	ld	bc,1
+EliasLoop	adc	a,a
+		jr	nz,NoFetch
+		sbc	a,(hl)
+		dec	hl
+		rla
+NoFetch		ret	nc
+		add	a,a
+		rl	c
+		rl	b
+		jr	EliasLoop

cpclib-asm/assets/uncrunch/bzpack_backward_bx2.asm

@@ -0,0 +1,51 @@
+; Copyright (c) 2025, Milos "baze" Bazelides
+; This code is licensed under the BSD 2-Clause License.
+
+; Reverse BX2 decoder (57 bytes with setup, 48 bytes excluding setup).
+; This work is inspired by Einar Saukas' ZX2 (https://github.com/einar-saukas/ZX2).
+
+		xor	a
+		ld	b,a
+		ld	c,a
+		ld	hl,SrcAddr
+		ld	de,DstAddr
+
+DecodeLoop	call	EliasGamma
+		rla
+		jr	nc,NewOffset
+
+		lddr
+
+		call	EliasGamma
+		rla
+		jr	c,RepOffset
+
+NewOffset	ex	af,af'
+		ld	a,(hl)
+		or	a
+		ret	z		; Option to include the end-of-stream marker.
+		ex	af,af'
+		dec	hl
+		inc	bc
+
+RepOffset	push	hl
+		ex	af,af'
+		ld	h,0
+		ld	l,a
+		ex	af,af'
+		add	hl,de
+		lddr
+		pop	hl
+		jr	DecodeLoop
+
+EliasGamma	inc	c
+EliasLoop	add	a,a
+		jr	nz,NoFetch
+		sbc	a,(hl)
+		dec	hl
+		rla
+NoFetch		ret	nc
+		add	a,a
+		rl	c
+		rl	b
+		jr	EliasLoop

cpclib-asm/assets/uncrunch/bzpack_backward_ef8.asm

@@ -0,0 +1,48 @@
+; Copyright (c) 2021, Aleksey "introspec" Pichugin, Milos "baze" Bazelides, Pavel "Zilog" Cimbal
+; This code is licensed under the BSD 2-Clause License.
+
+; Reverse EF8 decoder (39 bytes with setup, 30 bytes excluding setup).
+
+; If the decoder is launched from ZX Spectrum BASIC, the setup can be optimized by using
+; the initial values of BC and A:
+
+;		ld	h,b
+;		ld	l,b
+;		ld	de,DstAddr
+
+; This reduces the decoder to 34 bytes if these assumptions are met:
+
+; 1) The compressed stream is placed immediately above the entry point.
+; 2) The end-of-stream marker is omitted, and the final block overwrites opcodes after LDDR.
+; 3) The start address is either #7F80 (BC = #7F80, A = #80) or #BFC0 (BC = #BFC0, A = #C0).
+;    For the latter, the first literal must be at least 2 bytes long.
+
+		ld	hl,SrcAddr
+		ld	de,DstAddr
+		ld	a,128
+		ld	c,a
+
+EliasGamma	add	a,a
+		rl	c
+		ret	z		; Option to include the end-of-stream marker.
+DecodeLoop	add	a,a
+		jr	nz,NoFetch
+		ld	b,a
+		sbc	a,(hl)
+		dec	hl
+		rla
+NoFetch		jr	c,EliasGamma
+		rla
+		jr	c,CopyBytes
+		push	hl
+		ld	l,(hl)
+		ld	h,b
+		add	hl,de
+;		inc	hl		; Option to extend the offset range.
+		inc	bc
+CopyBytes	lddr
+		inc	c
+		jr	c,DecodeLoop
+		pop	hl
+		dec	hl
+		jr	DecodeLoop

cpclib-asm/assets/uncrunch/bzpack_backward_lzm.asm

@@ -0,0 +1,25 @@
+; Copyright (c) 2017, Milos "baze" Bazelides
+; This code is licensed under the BSD 2-Clause License.
+
+; Reverse LZM decoder (27 bytes with setup, 19 bytes excluding setup).
+
+		ld	hl,SrcAddr
+		ld	de,DstAddr
+		ld	b,0
+
+DecodeLoop	ld	c,(hl)
+		dec	hl
+		srl	c
+		ret	z		; Option to include the end-of-stream marker.
+;		inc	c		; Option to extend the block length.
+		jr	c,CopyBytes
+		push	hl
+		ld	l,(hl)
+		ld	h,b
+		add	hl,de
+;		inc	hl		; Option to extend the offset range.
+CopyBytes	lddr
+		jr	c,DecodeLoop
+		pop	hl
+		dec	hl
+		jr	DecodeLoop