hyprsettings/flake.nix at master · acropolis914/hyprsettings · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
{
  description = "HyprSettings - A configurator for hyprland.conf";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs = { self, nixpkgs, flake-utils, ... }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = nixpkgs.legacyPackages.${system};
      in
      {
        packages = rec {
          default = pkgs.callPackage ./default.nix { };
          hyprsettings = default;
        };

        apps = {
          default = {
            type = "app";
            program = "${self.packages.${system}.default}/bin/hyprsettings";
          };
        };

        devShells.default = pkgs.mkShell {
          buildInputs = with pkgs; [
            python3
            python3Packages.pywebview
            python3Packages.tomlkit
            python3Packages.rich
            python3Packages.pygobject3
            python3Packages.packaging
            python3Packages.flask
            python3Packages.flask-cors
            python3Packages.python-dotenv
            gtk3
            gobject-introspection
            webkitgtk_4_1
          ];
        };
      }
    )
    // {
      nixosModules.default = { config, lib, pkgs, ... }:
        with lib;
        let
          system = pkgs.stdenv.hostPlatform.system;
        in {
          options.programs.hyprsettings = {
            enable = mkEnableOption "HyprSettings configuration tool";

            package = mkOption {
              type = types.package;
              description = "The HyprSettings package to use";
              default = self.packages.${system}.default;
            };
          };

          config = mkIf config.programs.hyprsettings.enable {
            environment.systemPackages = [ config.programs.hyprsettings.package ];
          };
        };
    };
}