scaling_agent.tf

resource "aws_cloudwatch_log_group" "scaling_agent" {
  name              = "/aws/lambda/${var.project_name}-scaling-agent"
  retention_in_days = 14
}

# The policy layer. Runs on a schedule: reads the scheduler's desired-vs-current
# worker count and asynchronously invokes N worker Lambdas to close the gap.
# Scale-down is implicit — workers self-retire at their lifetime, so the agent
# never has to kill anything (mirrors the Fused rt_scaling design).
resource "aws_lambda_function" "scaling_agent" {
  function_name = "${var.project_name}-scaling-agent"
  role          = aws_iam_role.scaling_agent.arn
  package_type  = "Image"
  image_uri     = "${aws_ecr_repository.scaling_agent.repository_url}:${var.worker_image_tag}"

  memory_size = 256
  timeout     = 60

  vpc_config {
    subnet_ids         = module.vpc.private_subnets
    security_group_ids = [aws_security_group.worker.id]
  }

  environment {
    variables = {
      SCHEDULER_DASHBOARD = local.scheduler_dashboard
      WORKER_FUNCTION_ARN = aws_lambda_function.worker.arn
      MAX_WORKERS         = tostring(var.max_workers)
    }
  }

  depends_on = [aws_cloudwatch_log_group.scaling_agent]
}

resource "aws_scheduler_schedule" "scaling_agent" {
  name       = "${var.project_name}-scaling-agent"
  group_name = "default"

  flexible_time_window {
    mode = "OFF"
  }

  schedule_expression = var.scaling_interval

  target {
    arn      = aws_lambda_function.scaling_agent.arn
    role_arn = aws_iam_role.scheduler_invoke.arn
  }
}