CMakeLists.txt

cmake_minimum_required(VERSION 3.22)
project(experimental_behaviors CXX)

find_package(moveit_studio_common REQUIRED)
moveit_studio_package()

set(THIS_PACKAGE_INCLUDE_DEPENDS control_msgs geometry_msgs moveit_pro_behavior_interface pluginlib moveit_studio_common behaviortree_cpp tl_expected)
foreach(package IN ITEMS ${THIS_PACKAGE_INCLUDE_DEPENDS})
  find_package(${package} REQUIRED)
endforeach()

add_library(
  experimental_behaviors
  SHARED
  src/create_interface_value.cpp
  src/create_dynamic_interface_group_values.cpp
  src/get_dynamic_interface_group_values.cpp
  src/get_interface_value_from_group.cpp
  src/access_interface_value_from_group.cpp
  src/get_pose_stamped_from_topic.cpp
  src/publish_dynamic_interface_group_values.cpp
  src/get_blackboard_by_key.cpp
  src/set_blackboard_by_key.cpp
  src/register_behaviors.cpp)
target_include_directories(
  experimental_behaviors
  PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
         $<INSTALL_INTERFACE:include>)
ament_target_dependencies(experimental_behaviors
                          ${THIS_PACKAGE_INCLUDE_DEPENDS})

# Install Libraries
install(
  TARGETS experimental_behaviors
  EXPORT experimental_behaviorsTargets
  ARCHIVE DESTINATION lib
  LIBRARY DESTINATION lib
  RUNTIME DESTINATION bin
  INCLUDES
  DESTINATION include)

if(BUILD_TESTING)
  moveit_pro_behavior_test(experimental_behaviors)
endif()

# Export the behavior plugins defined in this package so they are available to
# plugin loaders that load the behavior base class library from the
# moveit_studio_behavior package.
pluginlib_export_plugin_description_file(
  moveit_pro_behavior_interface experimental_behaviors_plugin_description.xml)

ament_export_targets(experimental_behaviorsTargets HAS_LIBRARY_TARGET)
ament_export_dependencies(${THIS_PACKAGE_INCLUDE_DEPENDS})
ament_package()