elysiumtweaks-ext/build.gradle at master · ElysiumCraftMC/elysiumtweaks-ext · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
plugins {
    id 'java'
    id 'eclipse'
    id 'org.jetbrains.gradle.plugin.idea-ext' version '1.1.8'
}

group = 'codes.dreaming'
version = '1.1'

repositories {
    mavenCentral()
    maven {
        name = "papermc-repo"
        url = "https://repo.papermc.io/repository/maven-public/"
    }
    maven {
        name = "sonatype"
        url = "https://oss.sonatype.org/content/groups/public/"
    }
    exclusiveContent {
        forRepository { flatDir { dirs("libs") } }
        filter { includeGroup("local") }
    }
    maven {
        name= 'arim-mvn-lgpl3'
        url = 'https://mvn-repo.arim.space/lesser-gpl3/'
    }
    maven {
        name= 'arim-mvn-gpl3'
        url = 'https://mvn-repo.arim.space/gpl3/'
    }
    maven {
        name= 'arim-mvn-agpl3'
        url = 'https://mvn-repo.arim.space/affero-gpl3/'
    }
}

dependencies {
    compileOnly("local:DreamingQueue-1.2")
    compileOnly("io.netty:netty-buffer:4.1.117.Final")
    compileOnly("io.netty:netty-handler:4.1.117.Final")

    compileOnly "net.luckperms:api:${luckpermsApi_version}"
    compileOnly("com.velocitypowered:velocity-api:3.4.0-SNAPSHOT")
    annotationProcessor("com.velocitypowered:velocity-api:3.4.0-SNAPSHOT")
    compileOnly("space.arim.libertybans:bans-api:1.1.0-RC2")
}

def targetJavaVersion = 17
java {
    toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'
    options.release.set(targetJavaVersion)
}

def templateSource = file('src/main/templates')
def templateDest = layout.buildDirectory.dir('generated/sources/templates')
def generateTemplates = tasks.register('generateTemplates', Copy) { task ->
    def props = ['version': project.version]
    task.inputs.properties props

    task.from templateSource
    task.into templateDest
    task.expand props
}

sourceSets.main.java.srcDir(generateTemplates.map { it.outputs })

project.idea.project.settings.taskTriggers.afterSync generateTemplates
project.eclipse.synchronizationTasks(generateTemplates)