IronJetpacks/build.gradle at 26.1 · BlakeBr0/IronJetpacks · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
plugins {
    id 'java-library'
    id 'eclipse'
    id 'idea'
    id 'maven-publish'
    id 'net.neoforged.moddev' version '2.0.141'
}

version = '26.1.2-9.0.3'
group = 'com.blakebr0.ironjetpacks'

base {
    archivesName = 'IronJetpacks'
}

java.toolchain.languageVersion = JavaLanguageVersion.of(25)

println "Java: ${System.getProperty 'java.version'}, JVM: ${System.getProperty 'java.vm.version'} (${System.getProperty 'java.vendor'}), Arch: ${System.getProperty 'os.arch'}"

repositories {
    maven { url 'https://maven.blakesmods.com' }
    maven { url 'https://maven.blamejared.com' }
    maven { url 'https://maven.theillusivec4.top' }
    maven {
        url 'https://cursemaven.com'
        content {
            includeGroup 'curse.maven'
        }
    }
    mavenLocal()
}

neoForge {
    version = neo_version

    runs {
        client {
            client()
        }

        server {
            server()
        }

        configureEach {
            systemProperty 'forge.logging.markers', 'REGISTRIES'
            systemProperty 'terminal.jline', 'true'
            logLevel = org.slf4j.event.Level.DEBUG
            ideName = "IronJetpacks - ${it.ideName.get()}"
        }
    }

    mods {
        ironjetpacks {
            sourceSet(sourceSets.main)
        }
    }
}

configurations {
    runtimeClasspath.extendsFrom localRuntime
}

dependencies {
    implementation "com.blakebr0.cucumber:Cucumber:${cucumber_version}"
    implementation "curse.maven:controllable-317269:${controllable_version}"
    implementation "curse.maven:framework-549225:${framework_version}"

    runtimeOnly "top.theillusivec4.curios:curios-neoforge:${curios_version}"
    runtimeOnly "curse.maven:jade-324717:${jade_version}"
    runtimeOnly "mezz.jei:jei-${minecraft_version}-neoforge:${jei_version}"

    compileOnly "top.theillusivec4.curios:curios-neoforge:${curios_version}:api"
    compileOnly "mezz.jei:jei-${minecraft_version}-common-api:${jei_version}"
    compileOnly "mezz.jei:jei-${minecraft_version}-neoforge-api:${jei_version}"
}

java.withSourcesJar()

tasks.withType(ProcessResources).configureEach {
    var replaceProperties = [
            mod_version            : version.split('-').last(),
            cucumber_version       : cucumber_version.split('-').last(),
    ]
    inputs.properties replaceProperties

    filesMatching(['META-INF/neoforge.mods.toml']) {
        expand replaceProperties
    }
}

publishing {
    publications {
        maven(MavenPublication) {
            from components.java
        }
    }

    repositories {
        maven {
            url = 'https://maven.blakesmods.com'

            credentials {
                username = System.getenv('BLAKESMODS_MAVEN_USERNAME')
                password = System.getenv('BLAKESMODS_MAVEN_PASSWORD')
            }

            authentication {
                basic(BasicAuthentication)
            }
        }
    }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'
}

idea {
    module {
        downloadSources = true
        downloadJavadoc = true
    }
}