Oculus/build.gradle at 7a06375991b6c06986b93a5e92d7220edd3eb881 · Asek3/Oculus · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
plugins {
	id 'com.github.johnrengelman.shadow' version '8.1.1'
	id 'dev.architectury.loom' version '1.4-SNAPSHOT'
	id 'maven-publish'
}

loom {
	silentMojangMappingsLicense()
	accessWidenerPath = file("src/main/resources/iris.accesswidener")

	forge {
		convertAccessWideners = true
		mixinConfigs = [
				"mixins.oculus.json",
				"mixins.oculus.fantastic.json",
				"mixins.oculus.vertexformat.json",
				"mixins.oculus.bettermipmaps.json",
				"mixins.oculus.fixes.maxfpscrash.json",
				"oculus-batched-entity-rendering.mixins.json",
				"mixins.oculus.compat.sodium.json",
				"mixins.oculus.compat.indigo.json",
				"mixins.oculus.compat.indium.json",
				"mixins.oculus.compat.dh.json",
				"mixins.oculus.compat.pixelmon.json"
		]
	}
	mixin.defaultRefmapName = "oculus-mixins-refmap.json"
}

configurations {
	shadow {
		transitive = false
	}
}

sourceCompatibility = JavaVersion.VERSION_17
targetCompatibility = JavaVersion.VERSION_17

archivesBaseName = "${project.archives_base_name}-mc${project.minecraft_version}"
version = project.mod_version
group = project.maven_group

sourceSets {
	desktop {
	}

	vendored {
		java {
			compileClasspath += main.compileClasspath
		}
	}

	sodiumCompatibility {
		java {
			compileClasspath += main.compileClasspath
			compileClasspath += main.output
		}
	}

	main {
		java {
			compileClasspath += vendored.output
			runtimeClasspath += vendored.output
		}
	}
}

loom {
	runs {
		client {
			mods {
				oculus {
					sourceSet sourceSets.desktop
					sourceSet sourceSets.main
					sourceSet sourceSets.vendored
					sourceSet sourceSets.sodiumCompatibility
				}
			}
		}
	}
}

repositories {
	maven {
		name = "CurseForge"
		url = "https://cursemaven.com"
		content {
			includeGroup "curse.maven"
		}
	}
	maven {
		name = "Modrinth"
		url = "https://api.modrinth.com/maven"
		content {
			includeGroup "maven.modrinth"
		}
	}
	maven {
		url "https://maven.blamejared.com/"
	}
	maven {
		url "https://maven.neoforged.net/releases"
	}
	mavenCentral()
}

dependencies {
	minecraft "com.mojang:minecraft:${minecraft_version}"
	mappings loom.officialMojangMappings()
	forge "net.minecraftforge:forge:${minecraft_version}-${forge_version}"

	modImplementation "org.embeddedt:embeddium-${minecraft_version}:${embeddium_version}"
	modCompileOnly("maven.modrinth:distanthorizonsapi:3.0.0")

	forgeRuntimeLibrary(implementation(shadow(project(path: ":glsl-relocated", configuration: "bundledJar")))) {
		transitive = false
	}
	forgeRuntimeLibrary(implementation(include("org.anarres:jcpp:1.4.14")))
}

processResources {
	inputs.property "version", project.version

	filesMatching("META-INF/mods.toml") {
		expand "version": project.version
	}
}

shadowJar {
	configurations = [project.configurations.shadow]

	from jar.archiveFile

	relocate 'org.apache.commons.collections4', 'oculus.org.apache.commons.collections4'

	archiveClassifier.set "shadow"

	manifest {
		attributes(
				'Main-Class': 'net.irisshaders.iris.LaunchWarn'
		)
	}
}

remapJar {
	inputFile.set shadowJar.archiveFile
	dependsOn shadowJar
}

jar {
	from sourceSets.sodiumCompatibility.output
	from sourceSets.vendored.output
	from sourceSets.desktop.output
}

java {
	withSourcesJar()
}

sourcesJar {
	from sourceSets.sodiumCompatibility.allSource
	from sourceSets.vendored.allSource
	from sourceSets.desktop.allSource
}

publishing {
	publications {
		mavenJava(MavenPublication) {
			from components.java
		}
	}

	repositories {
	}
}