kotlin-hustlehub/build.gradle.kts at dev · Android-Community-MUST/kotlin-hustlehub · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
plugins {
    alias(libs.plugins.android.application) apply false
    alias(libs.plugins.kotlin.android) apply false
    alias(libs.plugins.kotlin.compose) apply false
    alias(libs.plugins.hilt) apply false
    alias(libs.plugins.ksp) apply false
    alias(libs.plugins.google.services) apply false
    alias(libs.plugins.firebase.crashlytics) apply false
    alias(libs.plugins.firebase.perf) apply false
    alias(libs.plugins.secrets.gradle.plugin) apply false
    alias(libs.plugins.kotlin.serialization) apply false
    alias(libs.plugins.ktlint) apply false
    alias(libs.plugins.detekt) apply false
}

subprojects {
    apply(plugin = "org.jlleitschuh.gradle.ktlint")
    configure<org.jlleitschuh.gradle.ktlint.KtlintExtension> {
        // Don't fail build on style issues during development
        ignoreFailures.set(true)

        // Use the .editorconfig for rule configuration
        android.set(true)

        // Report but don't fail
        reporters {
            reporter(org.jlleitschuh.gradle.ktlint.reporter.ReporterType.PLAIN)
            reporter(org.jlleitschuh.gradle.ktlint.reporter.ReporterType.CHECKSTYLE)
        }

        // Filter out generated files
        filter {
            exclude("**/generated/**")
            include("**/kotlin/**")
        }
    }

    apply(plugin = "io.gitlab.arturbosch.detekt")
    configure<io.gitlab.arturbosch.detekt.extensions.DetektExtension> {
        buildUponDefaultConfig = true
        allRules = false
        ignoreFailures = true
        config.setFrom(files("$rootDir/detekt.yml"))
        tasks.withType<io.gitlab.arturbosch.detekt.Detekt>().configureEach {
            buildUponDefaultConfig = true
            allRules = false
            config.setFrom(files("$rootDir/detekt.yml"))
        }
    }
}

tasks.register("qualityCheck") {
    group = "verification"
    description = "Runs ktlintFormat, ktlintCheck, detekt, and Android lint."
    dependsOn(":app:ktlintFormat", ":app:ktlintCheck", ":app:detekt", ":app:lint")
}

tasks.register("checkAll") {
    group = "verification"
    description = "Runs ktlintFormat, ktlintCheck, detekt, and Android lint."
    dependsOn("qualityCheck")
}